Disk space monitoring script for windows

' Constants for drive types
Const Unknown = 0
Const Removable = 1
Const Fixed = 2
Const Remote = 3
Const CDROM = 4
Const RAMDisk = 5

' Send a mail message
Sub SendMail(Sender, Recipient, Subject, Message,Server,Port)
Set objEmail = CreateObject("CDO.Message")
objEmail.From = Sender
objEmail.To = Recipient
objEmail.Subject = Subject
objEmail.Textbody = Message
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = Server
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = Port
objEmail.Configuration.Fields.Update()
objEmail.Send
End Sub

' get current computer name (from system environment variables)
Function GetCurrentComputerName
set oWsh = WScript.CreateObject("WScript.Shell")
set oWshSysEnv = oWsh.Environment("PROCESS")
GetCurrentComputerName = oWshSysEnv("COMPUTERNAME")
End Function

' get free space report
Function GetFreeSpaceReport
set oFs = WScript.CreateObject("Scripting.FileSystemObject")
set oDrives = oFs.Drives
for each oDrive in oDrives
Select case oDrive.DriveType
Case Fixed
GetFreeSpaceReport = GetFreeSpaceReport & oDrive.DriveLetter & ": " & Round(oDrive.FreeSpace/(1024*1024)) & "MB free (" & Round(100 * (oDrive.FreeSpace/oDrive.TotalSize),2) & "%)" & vbcrlf
End Select
next
End Function

<job>
<script src="lib_diskspace.vbs" language="vbscript" />
<script language="vbscript">
'====================================================================================
' Begin main code
'====================================================================================
' general constants
Const MailServer = "192.168.166.1" ' Mail Server to use for SMTP
Const MailServerPort = "25" ' SMTP Port used at Mail server (25 is default)
Const MailTo = "mark@lynchconsulting.com.au" ' Who should be notified
Const MailFrom = "server@lynchconsulting.com.au"

str = ""
subject = ""

strComputerName = GetCurrentComputerName ' get name only once for performance reasons
subject = "Drive Space Report " & strComputerName
str = str & strComputerName & vbcrlf
str = str & GetFreeSpaceReport

'Output to screen - useful for debugging
Msgbox str

'Send mail to administrator
SendMail MailFrom , MailTo , subject , str, MailServer , MailServerPort
</script>
</job>